Desarrollar con el IDE Arduino


#1

Hola, soy nuevo con espino y recién lo hice funcionar, con el ejemplo de servdor web en la sección de Wifi, pero quisiera saber si alguien tiene algún código que me ayude a interacuar con las entradas y salidas del Arduino y una pagina web en forma:

Ejemplo que pueda prender y apagar un led mediante un botón de la pagina web.

Saludos.


#2

Hola @cso20002009, te comparto un ejemplo que he utilizado para algunos cursos de ESPino:

#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <ESP8266WebServer.h>
#include <ESP8266mDNS.h>
 
const char* ssid = "TU SSID";
const char* password = "TU PASSWORD";
MDNSResponder mdns;

ESP8266WebServer server(80);

const int led = 4;

void handleRoot() {
  
  server.send(200, "text/html", "<html><head> <meta charset=\"utf-8\"> <title>ESPino</title></head><body> <h1>Control de LEDs</h1> <p>Presiona un bot\u00F3n</p><a href=\"/on\"><button>On</button></a> <a href=\"/off\"><button>Off</button></a></body></html>");
  
}

void ledOn()
{
  digitalWrite(led, LOW);
  server.send(200, "text/plain", "On");
}

void ledOff()
{
  digitalWrite(led, HIGH);
  server.send(200, "text/plain", "Off");
}

void handleNotFound(){
  
  String message = "File Not Found\n\n";
  message += "URI: ";
  message += server.uri();
  message += "\nMethod: ";
  message += (server.method() == HTTP_GET)?"GET":"POST";
  message += "\nArguments: ";
  message += server.args();
  message += "\n";
  for (uint8_t i=0; i<server.args(); i++){
    message += " " + server.argName(i) + ": " + server.arg(i) + "\n";
  }
  server.send(404, "text/plain", message);
  
}
 
void setup(void){
  pinMode(led, OUTPUT);
  digitalWrite(led, 0);
  Serial.begin(115200);
  WiFi.begin(ssid, password);
  Serial.println("");

  // Wait for connection
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("Connected to ");
  Serial.println(ssid);
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
  
  if (mdns.begin("rod", WiFi.localIP())) {
    Serial.println("MDNS responder started");
  }
  
  server.on("/", handleRoot);

  server.on("/on", ledOn);
  server.on("/off", ledOff);
  
  server.on("/inline", [](){
    server.send(200, "text/plain", "this works as well");
  });

  server.onNotFound(handleNotFound);
  
  server.begin();
  Serial.println("HTTP server started");
}
 
void loop(void){
  server.handleClient();
} 

Asegúrate de sustituir los valores de ssid y password por los que correspondan a tu red WiFi.

Este ejemplo hace que el ESPino sirva una página web a la que puedes acceder en http://<la ip del ESPino>/ (Puedes obtener la ip viendo la salida de la terminal serial del ESPino al conectarse).

La página web está definida en html y se ve algo así:

Al presionar un botón se va a encender o apagar el LED Verde del ESPino (conectado al pin 4).

Nota: Al poner código HTML como cadena de texto en C hay que “escapar” algunos caracteres especiales con “”. Esto lo puedes hacer fácilmente con herramientas que encuentras en línea como esta: http://www.freeformatter.com/javascript-escape.html

Espero que te sirva. saludos.


#3

Gracias, lo revisare y te comento despues.